哎呀呀，我的combin14单元为什么杀不死呢？

我在做地铁车站的计算，用beam3单元模拟墙、板和柱，用combin14单元当做地层弹簧来模拟车站底板与地层的接触，我的初衷是只希望combin14受压而不受拉，因为实际情况时车站只会挤压下面的土层而土层不可能对车站产生拉力，所以，当其受拉时，为了更符合实际，我就用ekill命令把受拉的combin14杀死，这时问题就出来了，ekill命令竟然杀不死受拉combin14单元，还弹出一个提示框，如下所示，这是问什么呢，希望各位网友朋友们能给解释解释，谢谢了！还有，我对combin14的非线性不是太熟，针对我所说的只让combin14受压而不受拉，该如何对其参数进行设置呢，望达人们指教一下撒！

未命名.jpg

braver0617

2011年07月22日 20:31:50

2楼

自己先顶一个，这是我编的命令流，运行没一点问题，运行后能发现有的combin14受拉了，我用ekill命令就出现上面的框框了

/prep7
!定义单元类型
ET,1,BEAM3 !定义梁单元
ET,2,combin14 !定义弹簧单元

!定义截面尺寸，取一纵向跨度长度1米计算
SECTYPE,1,BEAM,RECT,,0 !拟定义侧墙截面1
SECOFFSET,CENT
SECDATA,1,0.6,0,0,0,0,0,0,0,0

SECTYPE,2,BEAM,RECT,,0 !拟定义为底板1截面2
SECOFFSET,CENT
SECDATA,1,0.8,0,0,0,0,0,0,0,0

SECTYPE,3,BEAM,RECT,,0 !拟定义为底板2截面3
SECOFFSET,CENT
SECDATA,1,0.8,0,0,0,0,0,0,0,0

SECTYPE,4,BEAM,RECT,,0 !拟定义为顶板截面4
SECOFFSET,CENT
SECDATA,1,0.7,0,0,0,0,0,0,0,0

SECTYPE,5,BEAM,RECT,,0 !拟定义为柱1截面5
SECOFFSET,CENT
SECDATA,1,0.08,0,0,0,0,0,0,0,0

SECTYPE,6,BEAM,RECT,,0 !拟定义为柱2截面6
SECOFFSET,CENT
SECDATA,1,0.365,0,0,0,0,0,0,0,0

SECTYPE,7,BEAM,RECT,,0 !拟定义为小侧墙截面7
SECOFFSET,CENT
SECDATA,1,1,0,0,0,0,0,0,0,0

!定义各截面实常数
!定义梁单元的面积、惯性矩和梁高
R,1,1*0.6,1*0.6*0.6*0.6/12,0.6,,,,
R,2,1*0.8,1*0.8*0.8*0.8/12,0.8,,,,
R,3,1*0.8,1*0.8*0.8*0.8/12,0.8,,,,
R,4,1*0.7,1*0.7*0.7*0.7/12,0.7,,,,
R,5,1*0.08,1*0.08*0.08*0.08/12,0.08,,,,
R,6,1*0.365,0.365*0.365*0.365/12,0.365,,,,
R,7,1*1,1/12,1,,,,

!定义弹簧单元的弹性系数
R,8,30*1e6,,,

!定义材料属性（MP,Lab,MAT,C0，C1，C2，C3，C4）
!衬砌材料属性,C40
mp,ex,1,32.5e9 !弹性模量
mp,prxy,1,0.3
mp,dens,1,2.5e3

!②建立几何模型
!创建隧道支护控制关键点

!底板
k,1,0,0
k,2,7.9,0
k,3,7.9,1.375
k,4,15.85,1.375
k,5,15.85,7.135
k,6,7.9,7.135

k,7,0,7.135

k,8,-7.9,7.135
k,9,-15.85,7.135
k,10,-15.85,1.375
k,11,-7.9,1.375
k,12,-7.9,0

!生成线
l,1,2
l,12,1

l,3,4
l,10,11

l,4,5
l,10,9

l,5,6
l,8,9
l,6,7
l,7,8

l,1,7

l,2,3
l,12,11
l,3,6
l,11,8

!③单元网格划分

!底板1
lsel,s,line,,1,2,1 !选择线1、2
lesize,all,0.5 !设置网格划分大小,长度为1
Latt,1,2,1,,,,2 !给线分配单元属性
lmesh,all !划分单元，此时划分的是选择的线

!底板2
lsel,s,line,,3,4,1 !选择线3、4
lesize,all,0.5 !设置网格划分大小,长度为1
Latt,1,3,1,,,,3 !给线分配单元属性
lmesh,all !划分单元，此时划分的是选择的线

!顶板
lsel,s,line,,7,10,1 !选择线7、8、9、10
lesize,all,0.5 !设置网格划分大小
latt,1,4,1,,,,4 !给线分配单元属性，3类实常数的3类截面
lmesh,all !划分单元

!侧板
lsel,s,line,,5,6,1 !选择线5、6
lesize,all,0.5 !设置网格划分大小
Latt,1,1,1,,,,1 !给线分配单元属性
lmesh,all !划分单元

!柱1
lsel,s,line,,11,,1 !选择线11
lesize,all,0.5
latt,1,5,1,,,,5 !分配单元属性，
lmesh,all

!柱2
lsel,s,line,,14,15,1
lesize,all,0.5
latt,1,6,1,,,,6 !分配单元属性，
lmesh,all

!柱3
lsel,s,line,,12,13,1
lesize,all,0.2
latt,1,7,1,,,,7
lmesh,all

!创建底板弹簧单元
nsel,s,loc,y,0 !选择底板节点，节点坐标y为0的所有节点，
ngen,2,300,all,,,,-1 !复制节点，并沿着y方向移动1个单位长度，形成弹簧的节点
!节点号码增量为300，复制两次，包含自己本身一次

nsel,s,node,,53,67
ngen,2,300,all,,,,-1

nsel,s,node,,51,
ngen,2,300,all,,,,-1

nsel,s,node,,35,50
ngen,2,300,all,,,,-1

!定义弹簧单元
type,2
mat,1 !为后面定义的单元确定单元类型
real,8 !为后面定义的弹簧赋予实常数

*do,i,1,33,1
e,i,i+300
*enddo

*do,i,35,50,1
e,i,i+300
*enddo

e,51,351
*do,i,53,67,1
e,i,i+300
*enddo

!⑤施加边界条件
!对弹簧施加约束
allsel,all
nsel,s,loc,y,-1
d,all,ux,0,,,,uy

nsel,s,node,,353,367
d,all,ux,0,,,,uy
nsel,s,node,,351,
d,all,ux,0,,,,uy

nsel,s,node,,335,350
d,all,ux,0,,,,uy

!⑥施加荷载
/solu
allsel,all
d,1,ux,0 !约束1号节点位移，这是为了约束结构的水平位移
acel,0,9.8,0 !施加重力加速度

!在梁单元上施加面荷载
!选择顶板梁单元
allsel,all
esel,s,real,,4
sfbeam,all,1,pres,-98200

!选择底板梁单元
allsel,all
esel,s,real,,3
sfbeam,all,1,pres,-118125

allsel,all
esel,s,real,,2
sfbeam,all,1,pres,-136820

!选择左侧梁单元
allsel,all
esel,s,real,,1
sfbeam,152,1,press,100400,89600
sfbeam,151,1,press,111200,100400
sfbeam,150,1,press,122000,111200
sfbeam,149,1,press,132800,122000
sfbeam,148,1,press,143600,132800
sfbeam,147,1,press,154400,143600
sfbeam,146,1,press,165200,154400
sfbeam,145,1,press,176000,165200
sfbeam,144,1,press,186800,176000
sfbeam,143,1,press,197600,186800
sfbeam,142,1,press,208400,197600
sfbeam,141,1,press,219200,208400

!选择右侧梁单元
sfbeam,140,1,press,-100400,-89600
sfbeam,139,1,press,-111200,-100400
sfbeam,138,1,press,-122000,-111200
sfbeam,137,1,press,-132800,-122000
sfbeam,136,1,press,-143600,-132800
sfbeam,135,1,press,-154400,-143600
sfbeam,134,1,press,-165200,-154400
sfbeam,133,1,press,-176000,-165200
sfbeam,132,1,press,-186800,-176000
sfbeam,131,1,press,-197600,-186800
sfbeam,130,1,press,-208400,-197600
sfbeam,129,1,press,-219200,-208400

allsel,all
esel,s,real,,7
sfbeam,205,1,press,223619.6429,219200
sfbeam,204,1,press,228039.2857,223619.6429
sfbeam,203,1,press,232458.9286,228039.2857
sfbeam,202,1,press,236878.5714,232458.9286
sfbeam,201,1,press,241298.2143,236878.5714
sfbeam,200,1,press,245717.8571,241298.2143
sfbeam,199,1,press,250137.5,245717.8571

sfbeam,198,1,press,-223619.6429,-219200
sfbeam,197,1,press,-228039.2857,-223619.6429
sfbeam,196,1,press,-232458.9286,-228039.2857
sfbeam,195,1,press,-236878.5714,-232458.9286
sfbeam,194,1,press,-241298.2143,-236878.5714
sfbeam,193,1,press,-245717.8571,-241298.2143
sfbeam,192,1,press,-250137.5,-245717.8571

!⑦求解
allsel
eplot
solve
finish

!⑧后处理
/post1
pldisp,1
!建立单元表
ETABLE,NI,SMISC,1 !单元I点轴力
ETABLE,NJ,SMISC,7 !单元J点轴力
ETABLE,QI,SMISC,2 !单元I点剪力
ETABLE,QJ,SMISC,8 !单元J点剪力
ETABLE,MI,SMISC,6 !单元I点弯矩
ETABLE,MJ,SMISC,12 !单元J点弯矩

ETABLE,REFL !更新单元表
PLLS,NI,NJ,1,0 !画轴力分布图
PLLS,QI,QJ,1,0 !画剪力分布图
PLLS,MI,MJ,-1,0 !画弯矩分布图

whumaomao

2011年07月24日 10:33:50

3楼

谁帮他解决这个问题，我给你加土木币和威望。

fengzi14

2011年07月25日 13:08:33

4楼

solu里开n-r选项
试试

fengzi14

2011年07月25日 13:10:49

5楼

COMBIN14 has longitudinal or torsional capability in 1-D, 2-D, or 3-D applications.
KEYOPT(2)
Degree of freedom selection for 1-D behavior:
0 --
Use KEYOPT(3) options
1 --
1-D longitudinal spring-damper (UX degree of freedom)
2 --
1-D longitudinal spring-damper (UY degree of freedom)
3 --
1-D longitudinal spring-damper (UZ degree of freedom)
4 --
1-D Torsional spring-damper (ROTX degree of freedom)
5 --
1-D Torsional spring-damper (ROTY degree of freedom)
6 --
1-D Torsional spring-damper (ROTZ degree of freedom)
7 --
Pressure degree of freedom element
8 --
Temperature degree of freedom element
Structural Analysis:
No damping capability; CV1 and CV2 are not allowed.
Only stress stiffening and large deflections are allowed.
KEYOPT(2) = 7 or 8 is not allowed.
The DAMP material property is not allowed.

braver0617

2011年07月26日 11:56:27

6楼

搞定了，在求解步骤里把牛顿拉普森选项设置为full就可以了，即在/solu命令后添加nropt,full命令

chenduzhe

2011年07月27日 09:15:42

7楼

太难了

一介图夫

2011年07月31日 13:28:14

8楼

我也想学ansys来着，要么装不上，要么出问题，悲剧啊

whumaomao

2011年07月31日 16:42:32

9楼

ANSYS安装是有点复杂，你只有严格按照安装文档多试几次。