2楼
FINI
/CLE
/PREP7
smrt,off
ET,1,SHELL63,,1
R,1,6.350 ! SHELL THICKNESS
MP,EX,1,3102.75
MP,NUXY,1,0.3
!CREATE FINITE ELEMENT MODEL
R1 = 2540 ! SHELL MID-SURFACE RADIUS
L = 254 ! HALF THE LENGTH
PI = 4*ATAN(1) ! VALUE OF PI COMPUTED
THETA = 0.1*180/PI ! 0.1 RADIANS CONVERTED TO DEGREES
CSYS,1 ! CYLINDRICAL CO-ORDINATE SYSTEM
N,1,R1,90 ! NODES 1 AND 2 ARE CREATED AT POINTS
N,2,R1,90,L ! A AND B RESPECTIVELY.
K,1,R1,90
K,2,R1,(90-THETA)
K,3,R1,90,L
K,4,R1,(90-THETA),L
ESIZE,,2 ! TWO DIVISION ALONG THE REGION BOUNDARY
A,1,3,4,2
AMESH,1
NUMMRG,NODE
!APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,Z,0
DSYM,SYMM,Z
NSEL,S,LOC,Y,90
DSYM,SYMM,X
NSEL,S,LOC,Y,(90-THETA)
D,ALL,UX,,,,,UY,UZ
NSEL,ALL
FINISH
SAVE,BUCKLE2,DB
RESUME,BUCKLE2,DB
/SOLUTION
ANTYPE,STATIC
NLGEOM,ON ! LARGE DEFLECTION TURNED ON
OUTRES,,1 ! WRITE SOLUTION ON RESULTS FILE FOR EVERY SUBSTEP
F,1,FY,-250 ! 1/4 TH OF THE TOTAL LOAD APPLIED DUE TO SYMMETRY
NSUBST,30 ! BEGIN WITH 30 SUBSTEPS
ARCLEN,ON,4
SOLVE
FINISH
/POST26
NSOL,2,1,U,Y ! STORE UY DISPLACEMENT OF NODE 1
NSOL,3,2,U,Y ! STORE UY DISPLACEMENT OF NODE 2
PROD,4,1,,,LOAD,,,4*250 ! TOTAL LOAD IS 4*250 DUE TO SYMMETRY
PROD,5,2,,,,,,-1 ! CHANGE SIGNS OF THE DISPLACEMENT VALUES
PROD,6,3,,,,,,-1
*GET,UY1,VARI,2,EXTREM,VMIN
*GET,UY2,VARI,3,EXTREM,VMIN
PRVAR,2,3,4 ! PRINT STORED INFORMATION
/AXLAB,X, DEFLECTION (MM)
/AXLAB,Y, TOTAL LOAD (N)
/GRID,1
/XRANGE,0,35
/YRANGE,-500,1050
XVAR,5
PLVAR,4 ! PLOT LOAD WITH RESPECT TO -UY OF
XVAR,6
PLVAR,4
FINISH
回复
