!倒三角钢管桁架，桁架上弦设3个荷载作用点，应可灵活运用，荷载作用间距为2倍的桁架单元间距，
!本命令流的检修荷载是针对大中和小型桁架有两种不同选择，请注意将不用的命令行用“!”屏蔽
/FILNAME,hj,1
/TITLE, writen by yuanyong of slecc
/REPLOT

/units,si !定义公制，米、千克、秒
/PREP7 !进入预处理
ET,1,BEAM188
ET,2,BEAM44

KEYOPT,2,2,1 !质量矩阵为简化的
KEYOPT,2,6,0 !不输出弯矩
KEYOPT,2,9,0 !输出中间点的个数为0
KEYOPT,2,10,0 !轴向不变形
KEYOPT,2,7,11 !I节点释放Y、Z两轴的转动，不承受弯距
KEYOPT,2,8,11 !j节点释放Y、Z两轴的转动，不承受弯距

!!******定义桁架参数***************************
hjps=8 !桁架榀数 *
pjj=3 !榀间距 *
hjgd=2.5 !桁架高度 *
hjkd=3 !桁架宽度 *
fgx1=0.30 !第一条管线距弦杆距离 *
f1=500 !第一条管线的竖向荷载 *
fgx2=0.30 !第二条管线距第一条管线距离 *
f2=500 !第二条管线的竖向荷载 *
fgx3=0.30 !第三条管线距第二条管线距离 *
f3=500 !第三条管线的竖向荷载 *
sxgwj=159 !上弦杆外径 *
sxgbh=7 !上弦杆壁厚 *
xxgwj=219 !下弦杆外径 *
xxgbh=9 !下弦杆壁厚 *
gtcfgwj=114!管托处腹杆外径 *
gtcfgbh=6!管托处腹杆外径 *
qtfgwj=76!其他处腹杆外径 *
qtfgbh=5!其他处腹杆外径 *
!**********************************************
!杆件节点!!
*do,i,1,hjps+1
!上弦节点
n,i, (i-1)*pjj,0,0
n,i+100,(i-1)*pjj,0,fgx1
n,i+200,(i-1)*pjj,0,fgx1+fgx2
n,i+300,(i-1)*pjj,0,fgx1+fgx2+fgx3
n,i+400,(i-1)*pjj,0,hjgd
!下弦节点
n,i+500,(i-1)*pjj,hjgd,hjkd/2
*enddo

!定义下弦杆件
sectype,1,beam,ctube,,0
secdata,0.5*(sxgwj-2*sxgbh)/1000,0.5*sxgwj/1000,36

!定义上弦杆件
sectype,2,beam,ctube,,0
secdata,0.5*(xxgwj-2*sxgbh)/1000,0.5*xxgwj/1000,36

!定义管托处腹杆件
sectype,3,beam,ctube,,0
secdata,0.5*(gtcfgwj-2*gtcfgbh)/1000,0.5*gtcfgwj/1000,36

!定义其他处腹杆件
sectype,4,beam,ctube,,0
secdata,0.5*(qtfgwj-2*qtfgbh)/1000,0.5*qtfgwj/1000,36


MP,EX,1,2E+11 !弹性模量
MP,nuxy,1,0.3 !泊松比
MP,DENS,1,7850 !密度

!连接下弦杆
type,1
mat,1
secnum,1
*do,i,1,hjps
e,i,i+1
e,i+400,i+401
*enddo

!连接上弦
type,1
mat,1
secnum,2
*do,i,1,hjps
e,i+500,i+501
*enddo

!连接下弦上放管托的横向腹杆（横杆与弦杆为固结），桁架端部第一根就是
type,1
mat,1
secnum,3
*do,i,1,(hjps/2)+1
e,2*(i-1)+1,2*(i-1)+101
e,2*(i-1)+101,2*(i-1)+201
e,2*(i-1)+201,2*(i-1)+301
e,2*(i-1)+301,2*(i-1)+401
*enddo

!连接下弦横向腹杆（横杆与弦杆为固结）
type,1
mat,1
secnum,4
*do,i,1,(hjps/2)
e,2*i,2*i+100
e,2*i+100,2*i+200
e,2*i+200,2*i+300
e,2*i+300,2*i+400
*enddo

!连接下弦斜杆（斜杆与弦杆为铰结）
type,2
mat,1
secnum,4
*do,i,1,(hjps/2)
e,i,i+401
e,i+(hjps/2)+1,i+400+(hjps/2)
*enddo

!连接侧面斜向腹杆
type,2
mat,1
secnum,4
*do,i,1,(hjps/2)
e,2*(i-1)+1,2*(i-1)+502
e,2*(i-1)+401,2*(i-1)+502

e,2*(i-1)+3,2*(i-1)+502
e,2*(i-1)+403,2*(i-1)+502
*enddo
!连接侧面竖向腹杆
*do,i,1,hjps+1
e,i,i+500
e,i+400,i+500
*enddo


finish
!定义约束及荷载
/SOL
D,1, ,0, , , ,UX,UY,UZ, , , !固定支座约束
D,401, ,0, , , ,UX,UY,UZ, , , !固定支座约束
D,hjps+1, ,0, , , ,UY,UZ, , , , !滑动支座约束
D,hjps+401, ,0, , , ,UY,UZ, , , , !滑动支座约束

*do,i,1,hjps/2+1 !横向腹杆加竖向集中力,
F,2*(i-1)+101,Fy,F1*(-1)
F,2*(i-1)+201,Fy,F2*(-1)
F,2*(i-1)+301,Fy,F3*(-1)
*enddo



!!********以下施加检修荷载，两个不能同时作用于桁架上，请根据桁架类型自主选择*******
!对于小型跨越（主跨<50m）,检修荷载为800N,分别作用在跨中上弦杆两个节点
f,1+hjps/2,Fy,-400
f,401+hjps/2,Fy,-400

!对于大、中型跨越（主跨》50m）,检修荷载为均布荷载2KN/平米,分别作用上弦杆两侧节点上,两个支座处不考虑
*do,i,1,hjps-1
f,i+1,Fy,-2000*0.5*hjkd*pjj
f,401+i,Fy,-2000*0.5*hjkd*pjj
*enddo


acel,0,10
allsel
antype,0
solve !求解
FINISH

/post1
!斜腹杆轴向直接应力
ETABLE, ,ls, 1
ETABLE, ,ls, 6
!轴向直接应力
ETABLE, ,SMISC, 31
ETABLE, ,SMISC, 36
!绕Y轴正方向的弯曲应力
ETABLE, ,SMISC, 32
ETABLE, ,SMISC, 37
!绕Y轴负方向的弯曲应力
ETABLE, ,SMISC, 33
ETABLE, ,SMISC, 38
!绕Z轴正方向的弯曲应力
ETABLE, ,SMISC, 34
ETABLE, ,SMISC, 39
!绕Z轴负方向的弯曲应力
ETABLE, ,SMISC, 35
ETABLE, ,SMISC, 40