探讨隧道开挖过程模拟方法

在网上看到有人编写这样一个例子隧道上下台阶开挖支护的模拟过程如下所示：
!施加约束
allsel
nsel,s,loc,x,x_zs
nsel,a,loc,x,x_yx
d,all,ux
nsel,s,loc,y,y_yx
d,all,uy

save,step0,db

!指定求解选项
/solu
nlgeom,on
nropt,full
pred,on
lnsrch,on
nsubst,10,50,10

!荷载步1,自重应力场
allsel
esel,s,type,,1,3,2
ekill,all

allsel
acel,,9.8
allsel
solve
save,step1,db
esel,s,live
eplot

!荷载步2,上台阶开挖，应力释放
!提取节点力
/post1
esel,s,mat,,3
nsle,s
nsel,r,ext
*get,n,node,,count
*dim,n_nf,array,n,3
*do,i,1,n
*get,n_nf(i,1),node,,num,min
nsel,u,,,n_nf(i,1)
*enddo
!*status,n_nf
*do,i,1,n
nsel,s,,,n_nf(i,1)
fsum
*get,n_nf(i,2),fsum,,item,fx
*get,n_nf(i,3),fsum,,item,fy
*enddo
!*status,n_nf
parsav,all,002,PARM

/solu
antype,,rest
!杀死上台阶土体单元
allsel
esel,s,mat,,3
ekill,all
!施加等效释放节点力
parres,,002,PARM
esel,s,mat,,3
nsle,s
nsel,r,ext
*do,i,1,n
f,n_nf(i,1),fx,0.65*n_nf(i,2)
f,n_nf(i,1),fy,0.65*n_nf(i,3)
*enddo

!约束死单元自由度
allsel
esel,s,live
nsle,s
nsel,inve
d,all,all

allsel
solve
save,step2,db
esel,s,live
eplot

!荷载步3
!删除节点力，激活上台阶支护和锚杆
allsel
esel,s,mat,,3
nsle,s
nsel,r,ext
fdele,all,all

esel,s,mat,,1,6,5
ealive,all

allsel
solve
save,step3,db

!荷载步4，下台阶开挖，应力释放
!提取节点力
/post1
esel,s,mat,,4
nsle,s
nsel,r,ext
*get,n,node,,count
*dim,n_nf,array,n,3
*do,i,1,n
*get,n_nf(i,1),node,,num,min
nsel,u,,,n_nf(i,1)
*enddo
!*status,n_nf
*do,i,1,n
nsel,s,,,n_nf(i,1)
fsum
*get,n_nf(i,2),fsum,,item,fx
*get,n_nf(i,3),fsum,,item,fy
*enddo
!*status,n_nf
parsav,all,002,PARM

/solu
antype,,rest
!杀死下台阶土体单元
allsel
ealive,all
esel,s,mat,,2,3,1
esel,a,mat,,4
ekill,all
!施加等效释放节点力
parres,,002,PARM
esel,s,mat,,4
nsle,s
nsel,r,ext
*do,i,1,n
f,n_nf(i,1),fx,0.65*n_nf(i,2)
f,n_nf(i,1),fy,0.65*n_nf(i,3)
*enddo

!约束死单元自由度
allsel
esel,s,live
nsle,s
nsel,inve
d,all,all

allsel
solve
save,step4,db
esel,s,live
eplot

!荷载步5
!删除节点力，激活下台阶支护
allsel
esel,s,mat,,4
nsle,s
nsel,r,ext
fdele,all,all

esel,s,mat,,2
ealive,all

allsel
solve
save,step5,db

请各位高人探讨一下，这程序才用的是多载荷步法，还是其他什么地应力自动释放方法，怎么看不明白，而且一般开挖支护是在一次求解中同步进行的，而这个程序却是分两步运行的，有什么区别吗？提取的节点力也没有采取反向啊，

[ 本帖最后由 tzz1997 于 2010-5-8 22:47 编辑 ]