2楼
/FINISH
/CLEAR
/COM,Structural !指定结构分析
/TITLE,TuSupStrAnal14231072 !定义工作标题
/FILNAM,support,1 !定义工作文件名
/PREP7 !进入前处理器
*set,dingEte,238780.00000 !定义标准组合，顶拱竖向恒载
*set,dingLive,20000.00000 !顶拱竖向活载
*set,yangEte,423057.50000 !仰拱竖向恒载
*set,yangLive,-5722.76767 !仰拱竖向活载
*set,ce1TopEte,112759.4311 !侧向层1顶部恒荷载
*set,ce1BotEte,130311.7959 !侧向层1底部恒荷载
*set,ce2TopEte,119269.4633 !侧向层2顶部恒荷载
*set,ce2BotEte,229116.8295 !侧向层2底部恒荷载
*set,ce3TopEte,239927.4613 !侧向层3顶部恒荷载
*set,ce3BotEte,244538.4488 !侧向层3底部恒荷载
*set,ceLive,8265.389106 !侧向活荷载
ET,1,BEAM188 !定义混凝土梁单元
SECTYPE,1,BEAM,RECT,,0
SECOFFSET,CENT
SECDATA,0.5,1.0,0,0,0,0,0,0,0,0,0,0 !定义截面形状和参数
MP,EX,1,3.1E10 !定义混凝土支护的弹性模量
MP,PRXY,1,0.2 !定义混凝土支护的泊松比
MP,DENS,1,2500 !定义混凝土支护的密度
NUMSTR,KP,1
NUMSTR,LINE,1
NUMSTR,AREA,1
NUMSTR,VOLU,1
CSYS,0
k, 1 ,5.529,1.646,.000, !生成圆弧端点
k, 2 ,5.700,3.350,.000,
k, 3 ,5.345,4.675,.000,
k, 4 ,.000,7.761,.000,
k, 5 ,-5.345,4.675,.000,
k, 6 ,-5.700,3.350,.000,
k, 7 ,-5.529,1.646,.000,
k, 8 ,-5.070,1.073,.000,
k, 9 ,5.070,1.073,.000,
k, 10 ,5.657,2.494,.000, !生成圆弧中点
LARC,1 ,2 ,10 !做出圆弧
k, 11 ,5.610,4.036,.000,
LARC,2 ,3 ,11
k, 12 ,3.086,6.934,.000,
LARC,3 ,4 ,12
k, 13 ,-3.086,6.934,.000,
LARC,4 ,5 ,13
k, 14 ,-5.610,4.036,.000,
LARC,5 ,6 ,14
k, 15 ,-5.657,2.494,.000,
LARC,6 ,7 ,15
k, 16 ,-5.369,1.304,.000,
LARC,7 ,8 ,16
k, 17 ,.000,.000,.000,
LARC,8 ,9 ,17
k, 18 ,5.369,1.304,.000,
LARC,9 ,1 ,18
/PNUM,LINE,1 !打开线号开关，方便观察
lsel,s,line,,1,9,1
LATT,1,1,1, , , , !给所选L1-L9线赋予材料特性
LESIZE,1,,,8,
LESIZE,2,,,8,
LESIZE,5,,,8,
LESIZE,6,,,8,
LESIZE,7,,,8,
LESIZE,9,,,8, !设置L1、L2、L5、L6、L7、L9即侧拱网格划分份数为8
LESIZE,3,,,20,
LESIZE,4,,,20, !设置L3、L4即顶拱网格划分份数为20
LESIZE,8,,,32, !设置L8即仰拱网格划分份数为32
lsel,all
TYPE, 1
MAT, 1
REAL,
ESYS, 0
SECNUM, 1
Lmesh,all !线网格划分，生成支护单元
/PNUM,NODE,1 !打开节点号开关，方便观察
PSPRNG,2,TRANS,120000000,1,0,
PSPRNG,3,TRANS,120000000,0.984807664856161,-0.173648677623978,
……中间都是加弹簧的，我省略了……
PSPRNG,1,TRANS,120000000,0.980150170065095,-0.198256510917965, !生成节点弹簧，长度为单位1，实际上弹簧长度并不影响结果。弹簧方向为该点对应弧的连心线方向或切线垂线方向。计算结果见计算书附件
EDELE,137
……省略……
EDELE,170 !删除顶拱脱离区弹簧，脱离区为90度
NDEL,137
……省略……
NDEL,170 !删除脱离区弹簧对应节点
SAVE,'support2mesh','db','C:\Users\Cyrus\Desktop\ansys\' !保存单元网格模型
FINISH
/SOL
ANTYPE,0 !定义分析类型：静力分析
ACEL,0,0,0
NSEL,S,NODE,,121,240,1 !选择隧道支护弹簧上所有外侧节点
d,all,uy,0 !对所选择节点约束X方向位移
d,all,ux,0 !对所选择节点约束Y方向位移
NSEL,S,NODE,,1,240,1
d,all,uz,0 !对所选择节点约束Z方向位移
allsel
fcum,add,, !使单元可分步加载
time,1 !进行标准组合求解，编1
FDELE,ALL,ALL !清除前一步荷载
*do,i,18,57
a=- dingEte
f,i,fy,a
*enddo !顶拱恒载
*do,i,18,57
a=- dingLive
f,i,fy,a
*enddo !顶拱活载
*do,i,81,113
a=yangEte
f,i,fy,a
*enddo !仰拱恒载
*do,i,81,113
a=yangLive
f,i,fy,a
*enddo !仰拱活载
*do,i,1,81
xlebel=NX(i)
a= ceLive
*if,xlebel,gt,0,then
a=0-a !右侧荷载符号
*elseif,xlebel,eq,0,then
a=0 !对称轴上没有侧荷载
*endif
f,i,fx,a
*enddo !
*do,i,114,120
xlebel=NX(i)
a= ceLive
*if,xlebel,gt,0,then
a=0-a !右侧荷载符号
*elseif,xlebel,eq,0,then
a=0 !对称轴上没有侧荷载
*endif
f,i,fx,a
*enddo !施加侧活载
*do,i,1,81
xlebel=NX(i)
ylebel=NY(i)
dp=11.8+(8.761-ylebel) !换算对应点埋深
*if,dp,le,12.8,then
a=ce1TopEte+(ce1BotEte-ce1TopEte)*(dp-11.8)/(12.8-11.8) !层1恒载
*elseif,dp,le,19.3,then
a=ce2TopEte+(ce2BotEte-ce2TopEte)*(dp-12.8)/(19.3-12.8) !层2恒载
*elseif,dp,le,19.561,then
a=ce3TopEte+(ce3BotEte-ce3TopEte)*(dp-19.3)/(19.561-19.3) !层3恒载
*endif
*if,xlebel,gt,0,then
a=0-a !右侧荷载符号
*elseif,xlebel,eq,0,then
a=0 !对称轴上没有侧荷载
*endif
f,i,fx,a
*enddo
*do,i,113,120
xlebel=NX(i)
ylebel=NY(i)
dp=11.8+(8.761-ylebel) !换算对应点埋深
*if,dp,le,12.8,then
a=ce1TopEte+(ce1BotEte-ce1TopEte)*(dp-11.8)/(12.8-11.8) !层1恒载
*elseif,dp,le,19.3,then
a=ce2TopEte+(ce2BotEte-ce2TopEte)*(dp-12.8)/(19.3-12.8) !层2恒载
*elseif,dp,le,19.561,then
a=ce3TopEte+(ce3BotEte-ce3TopEte)*(dp-19.3)/(19.561-19.3) !层3恒载
*endif
*if,xlebel,gt,0,then
a=0-a !右侧荷载符号
*elseif,xlebel,eq,0,then
a=0 !对称轴上没有侧荷载
*endif
f,i,fx,a
*enddo !顶拱侧拱底拱侧恒载
SAVE,'support3load-1biaozhun','db','C:\Users\Cyrus\Desktop\ansys\' !保存标准组合加载模型
allsel
SOLVE !进行求解
finish
/POST1
ETABLE,IMOMENT,SMISC,3 !制结构弯矩表
ETABLE,JMOMENT,SMISC,16
ETABLE,ISHEAR,SMISC,6 !制结构剪力表
ETABLE,JSHEAR,SMISC,19
ETABLE,ZHOULI-I,SMISC,1 !制结构轴力表
ETABLE,ZHOULI-J,SMISC,14
/TITLE,BENDINGMOMENTdistribution !定义弯矩分布标题
PLLS,IMOMENT,JMOMENT,-0.8,1 !绘制结构弯矩分布图
/TITLE,SHEARforcedistribution !定义剪力分布标题
PLLS,ISHEAR,JSHEAR,1,1 !绘制剪力分布图
/TITLE,ZHOULIforcedistribution !定义轴力分布标题
PLLS,ZHOULI-I,ZHOULI-J,-0.6,1 !绘制轴力分布图
回复
