曲线任意里程中边桩坐标正反算(CASIO fx-4800P计算器)程序

一、程序功能
本程序由一个主程序(TYQXJS)和两个子程??正算子程序(SUB1)、反算子程序(
SUB2)序构成，可以根据曲线段??直线、圆曲线、缓和曲线（完整或非完整型）的线
元要素（起点坐标、起点里程、起点切线方位角、线元长度、起点曲率半径、止点曲
率半径）及里程边距或坐标，对该曲线段范围内任意里程中边桩坐标进行正反算。另
外也可以将本程序中核心算法部分的两个子程序移植到其它相关的程序中，用于对曲
线任意里程中边桩坐标进行正反算。本程序也可以在CASIO fx-4500P计算器及 CASIO fx-4850P计算器上运行。
特别申明：(1). 适用于弧长小于2倍半径的各种线元坐标正反算，精度优
于1mm；
(2). 在引用该核心计算部分时，请注明来源。
二、源程序
1.主程序(TYQXJS)
"1.SZ => XY"："2.XY => SZ"：N：U"X0"：V"Y0"：O"S0"：G"F0"：H"LS"：P"R0"：R"
RN"：Q：C=1÷P：D=(P-R)÷(2HPR)：E=180÷π：N=1=>Goto 1：≠>Goto 2Δ←┘
Lbl 1：{SZ}：SZ：W=Abs(S-O)：Prog "SUB1"：X"XS"=X?
Y"YS"=Y?
F"FS"=F-90?
Goto 1←┘
Lbl 2：{XY}：XY：I=X：J=Y：Prog "SUB2"：S"S"=O+W?
Z"Z"=Z?
Goto 2

2. 正算子程序(SUB1)
A=0.1739274226：B=0.3260725774：K=0.0694318442：L=0.3300094782：F=1-L：
M=1-K：X=U+W(Acos(G+QEKW(C+KWD))+Bcos(G+QELW(C+LWD))+Bcos(G+QEFW
(C+FWD))+Acos(G+QEMW(C+MWD)))：Y=V+W(Asin(G+QEKW(C+KWD))+Bsin(G+
QELW(C+LWD))+Bsin(G+QEFW(C+FWD))+Asin(G+QEMW(C+MWD)))：F=G+QEW(C+
WD)+90：X=X+ZcosF：Y=Y+ZsinF

3. 反算子程序(SUB2)
T=G-90：W=Abs((Y-V)cosT-(X-U)sinT)：Z=0：Lbl 0：Prog "SUB1"：L=T+QEW(C+
WD)：Z=(J-Y)cosL-(I-X)sinL：AbsZ<1E-6=>Goto1：≠>W=W+Z：Goto 0Δ←┘
Lbl 1：Z=0：Prog "SUB1"：Z=(J-Y)÷sinF

三、使用说明
1、规定
(1) 以道路中线的前进方向（即里程增大的方向）区分左右；当线元往左偏时，
Q=-1；当线元往右偏时，Q=1；当线元为直线时，Q=0。
(2) 当所求点位于中线时，Z=0；当位于中线左铡时，Z取负值；当位于中线中线右
侧时，Z取正值。
(3) 当线元为直线时，其起点、止点的曲率半径为无穷大，以10的45次代替。
(4) 当线元为圆曲线时，无论其起点、止点与什么线元相接，其曲率半径均等于圆
弧的半径。
(5) 当线元为完整缓和曲线时，起点与直线相接时，曲率半径为无穷大，以10的45
次代替；与圆曲线相接时，曲率半径等于圆曲线的半径。止点与直线相接时，曲率半
径为无穷大，以10的45次代替；与圆曲线相接时，曲率半径等于圆曲线的半径。
(6) 当线元为非完整缓和曲线时，起点与直线相接时，曲率半径等于设计规定的
值；与圆曲线相接时，曲率半径等于圆曲线的半径。止点与直线相接时，曲率半径等
于设计规定的值；与圆曲线相接时，曲率半径等于圆曲线的半径。

2、输入与显示说明
输入部分：
1. SZ => XY
2. XY = > SZ
N ? 选择计算方式，输入1表示进行由里程、边距计算坐标 ；输入2表示由坐标反算
里程和边距。
X0 ？线元起点的X坐标
Y0 ？线元起点的Y坐标
S0 ？线元起点里程
F0 ？线元起点切线方位角
LS ？线元长度
R0 ？线元起点曲率半径
RN ？线元止点曲率半径
Q ？ 线 元左右偏标志(左偏Q=-1，右偏Q=1，直线段Q=0）
S ？ 正算时所求点的里程
Z ？正算时所求点距中线的边距(左侧取负，值右侧取正值，在中线上取零)
X ？反算时所求点的X坐标
Y ？反算时所求点的Y坐标
显示部分：
XS=××× 正算时，计算得出的所求点的X坐标
YS=××× 正算时，计算得出的所求点的Y坐标
FS=××× 正算时，所求点对应的中线点的切线方位角
S=××× 反算时，计算得出的所求点的里程
Z=××× 反算时，计算得出的所求点的边距

四、算例
某匝道的由五段线元（直线+完整缓和曲线+圆曲线+非完整缓和曲线+直线）组
成，各段线元的要素（起点里程S0、起点坐标X0 Y0、起点切线方位角F0、线元长度
LS、起点曲率半径R0、止点曲率半径RN、线 元左右偏标志Q）如下：
S0 X0 Y0 F0 LS R0 RN Q
500.000 19942.837 28343.561 125 16 31.00 269.256 1E45 1E45 0
769.256 19787.340 28563.378 125 16 31.00 37.492 1E45 221.75 -1
806.748 19766.566 28594.574 120 25 54.07 112.779 221.75 221.75 -1
919.527 19736.072 28701.893 91 17 30.63 80.285 221.75 9579.228 -1
999.812 19744.038 28781.659 80 40 50.00 100.000 1E45 1E45 0
1、正算
（注意：略去计算方式及线元要素输入，请自行根据所求点所在的线元输入线元
要素）
S=700 Z=-5 计算得 XS=19831.41785 YS=28509.72590
S=700 Z=0 计算得 XS=19827.33592 YS=28506.83837
S=700 Z= 5 计算得 XS=19823.25398 YS=28503.95084

S=780 Z=-5 计算得 XS=19785.25749 YS=28575.02270
S=780 Z=0 计算得 XS=19781.15561 YS=28572.16358
S=780 Z= 5 计算得 XS=19777.05373 YS=28569.30446

S=870 Z=-5 计算得 XS=19747.53609 YS=28654.13091
S=870 Z=0 计算得 XS=19742.68648 YS=28652.91379
S=870 Z= 5 计算得 XS=19737.83688 YS=28651.69668

S=940 Z=-5.123 计算得 XS=19741. 59118 YS=28722.05802
S=940 Z=0 计算得 XS=19736.47687 YS=28722.35642
S=940 Z= 3.009 计算得 XS=19733.47298 YS=28722.53168

2、 反算
X=19831.418 Y=28509.726 计算得 S=699.9999974 Z= -5 .00018164
X=19827.336 Y=28506.838 计算得 S=699.9996493 Z= 0.000145136
X=19823.25398 Y=28503.95084 计算得 S=699.9999985 Z= 5.000003137
X=19785.25749 Y=28575.02270 计算得 S=780.0000035 Z= -5 .000001663
X=19781.15561 Y=28572.16358 计算得 S=780.0000025 Z=- 0.000002979
X=19777.05373 Y=28569.30446 计算得 S=780.0000016 Z= 4.99999578

X=19747.536 Y=28654.131 计算得 S=870.0001137 Z= -4.99941049
X=19742.686 Y=28652.914 计算得 S=870.0003175 Z=- 0.00041814
X=19737.837 Y=28651.697 计算得 S=870.0002748 Z= 4.999808656

X=19741.5912 Y=28722.0580 计算得 S=939.9999786 Z= -5.123024937
X=19736.4769 Y=28722.3564 计算得 S=939.9999862 Z=- 0.000027710
X=19733.4730 Y=28722.5317 计算得 S=940.0000238 Z= 3.00898694

任意里程中边桩坐标正反算（CASIO fx-4800P计算器）程序


一、源程序(SZ-XY-SZ)
"1.SZ => XY"："2. XY => SZ"：N：U"X0"：V"Y0"：O"S0"：G"F0"：Q：Q=0=>R=1E-45：≠>
R△J=0：M=AbsQ：K=1-M：N=1=>Goto 1：≠>Goto 2△←┙
Lbl 1：{SZ}：SZ：L=S-O：B=90QL÷π÷R：F=G+B：E=F+B+90：C=LK+2MRsinQB：X"XS"
= U+Rec(C,F)+ZcosE?
Y"YS"=V+J+ZsinE?
Goto 1←┙
Lbl 2：W=G+90Q：E=U+Rec(R,W)：F=V+J←┙
Lbl 3：{XY}：XY：D=Pol(X-E,Y-F):T=J：J<0=>T=J+360△B=T-W-180M：P=Abs B：S"S"=O+
DKcosP+ MπRP÷180?
Z"Z"=DKsinB+MQ(R-D)?
Goto 3←┙
二、使用说明
1.由里程、中边桩计算坐标
启动程序后按以下提示输入数据：
N ？1 （N=1，由里程中边桩计算坐标；N≠1，由坐标反算里程及中边桩)
X0 ？142.353 (直线或圆曲线起点的X坐标）
Y0 ？368.166 (直线或圆曲线起点的Y坐标）
S0 ？155.252 (直线或圆曲线起点的里程）
F0 ？60°54′03″(直线或圆曲线起点的切线方位角）
Q ？-1 (当线元为直线时Q=0；当线元为圆曲线且左偏时Q=-1；当线元为圆曲线且
右偏时Q=1)
R ？ 100 (圆曲线的半径)
S ？ 194.016 (中线里程)
Z ？ -5.251 (中线左侧5.251m的边桩；在中线上Z=0，在左侧<0，在右侧Z>0)
显示计算结果
XS=172.7467767
YS=395.2316807
2.由坐标反算里程、中边桩
启动程序后按以下提示输入数据：
N ？2 （N=1，由里程中边桩计算坐标；N≠1，由坐标反算里程及中边桩)
X0 ？142.353 (直线或圆曲线起点的X坐标）
Y0 ？368.166 (直线或圆曲线起点的Y坐标）
S0 ？155.252 (直线或圆曲线起点的里程）
F0 ？60°54′03″(直线或圆曲线起点的切线方位角）
Q ？-1 (当线元为直线时Q=0；当线元为圆曲线且左偏时Q=-1；当线元为圆曲线且
右偏时Q=1)
R ？ 100 (圆曲线的半径)
X ？ 172.7467767 (待求里程及中边桩的点的X坐标)
Y ？ 395.2316807 (待求里程及中边桩的点的Y坐标)
显示计算结果
S=194.016
Z=-5.251
三、注意事项
1.本程序主要是针对市政道路工程中的直线和圆曲线而编制的，未考虑缓和曲线等
曲线的计算；
2.程序中“R=1E-45”的意思为10的-45次方，输入程序时切莫输错。
3.程序中设置的计算顺序是由小里程往大里程方向（即里程增大的方向），曲线左偏、右偏也是以里程增大的方向来区分的。

公路三维坐标控制系统高程控制部分(for 4850)

主程序DH

{SZ}:SZ
S≤S1＝＞N=1:Prog“HDAT”:GOTO 1△
S≤S2＝＞N=2:Prog“HDAT”:GOTO 1△
S≤S3＝＞N=3:Prog“HDAT”:GOTO 1△
……
Lbl 1:S ≤I ＝＞Q= F+G(S- E △
S ＞I ＝＞Q= F+G(S- E)+(-1)^J(S-I)^2/(2 M△
R= Q+11.75 P-0.03:”DH=”: Q= Q ?
Z=0＝＞Q= Q △
Z≠0＝＞Q= R △
{H}:H”H=”: T= Q-H
“△H=”: T= T ?
{ABKL}: T=Abs T: U= T / 8 : T ≤8＝＞W= TA+14+L△
T ＞8＝＞W=8A+B(T-8)+14+2Int U+L△
T ＞16＝＞W=8A+8B+K(T-16)+14+2 Int U+L△
“DW”: W= W ?
“△W”: D= W-Abs Z?

竖曲线数据库HDAT
N=1＝＞E= xxxx.xxx: F= xxxx.xxx: G= xxxx.xxx: J= xxxx.xxx: M= xxxx.xxx:
O= xxxx.xxx△N=2＝＞E= xxxx.xxx: F= xxxx.xxx: G= xxxx.xxx: J= xxxx.xxx: M= xxxx.xxx: O= xxxx.xxx△N=3＝＞E= xxxx.xxx: F= xxxx.xxx: G= xxxx.xxx: J= xxxx.xxx: M= xxxx.xxx: O= xxxx.xxx△
……
I= E- O

说明：
(1)变量赋值说明

E变坡点桩号
F变坡点高程
G变坡点前段坡比
I该段竖曲线起点桩号即高差改正值为零处桩号
J竖曲线系数 1为凸2为凹
M竖曲线半径
O 竖曲线切线长
P路面横坡（已在坐标反算程序中赋值）
Q路线设计高程，当Z=0时为中桩设计高程（或中分带边缘设计高程），当Z≠0
时为路基边缘设计高程
R 路基边缘设计高程
T：“△H”高差
V边坡分级，第n级坡
W开口、坡脚设计宽度（根据高差及坡比求得）可计算任意高度处的设计宽度
D宽差（当其为负?向中桩方向移相应宽度，当其为正则向外移相应宽度）
S、Z所测点对应桩号及距中桩处的距离
A、B、K横断面一、二、三级坡比
L附加宽度（以便根据横断面设计实际情况调整，象坠落台、护坡道、路堑处边沟设置宽度的不固定值设置及填方段为使路基满足设计的压实要求超填的宽度）
H实测高程
(2)编制思路
该程序编者根据工地的实际情况编制在此仅供一个编制思路，用户需根据实际情况进行修改。
注意：程序中有下划线处数据说明（单位：cm）
11.75为中央分隔带边缘距硬路肩宽度，该段横坡为一定值（超高段需加入超高计算子程序，另外在设计宽度计算时加入加宽子程序即可）
0．03为土路肩内外侧高差，因土路肩与行车道及硬路肩横坡不同，故分开计算。（用户需根据实际情况修改）
2 为平台设置宽度，第n级坡的平台设置总宽度即为2n. （用户需根据实际情况修改）
8 每级边坡设置高度.
14 路面设计宽度（路线中线处距土路肩边缘设计宽度）
该程序为公路三维控制系统中的一部分，即高程控制部分。该程序可与hanniu_1973老师的《曲线任意里程中边桩坐标正反算(CASIO fx-4850P)程序（第三次修改版）》及大部分坐标正反算程序联合使用（修改变量名后）。

求两直线交点(CASIO fx?4800P计算器)程序

;直线(x1, y1)-(x2, y2) 与直线 (x3, y3)-(x3, y4)的交点
Lbl 1：{ABCDEFGH}：A"X1"：B"Y1"：C"X2"：D"Y2"：E"X3"：F"Y3"：G"X4"：
H"Y4"：N=C-A：O=D-B：P=G-E：Q=H-F：K=QN-OP：U=NB-OA：V=PF-QE：
X"XP"=(PU-NV)÷K?
Y"YP="(QU-OV)÷K?
Goto 1

以上部分转自测量空间，欢迎大家一起讨论！最好是用计算器进行验算！

好东西,谢谢楼主的辛勤劳动!!!

CASIO fx-4800P 编程计算器测量程序集
一．SHI JU CE TU （视距测图）
1． 用途：该程序用于“经纬仪视距法碎部测量”时，计算测站点至碎部点间的平距及碎部点的高程。
2． 程序清单：
C“H0”：I：A“UP”：B“DOWN”：V“MIDDLE”：L：E=90-L ↙
D=100Abs（A-B）（cosE）2◢ H=（C+I）+DtanE-V
3． 程序说明：
H0——测站点高程；I——测站仪器高；UP——塔尺上丝读数；DOWN——塔尺下丝读数；MIDDLE——塔尺中丝读数；L——经纬仪竖盘读数盘左读数；D——测站点至碎部点间平距；H——碎部点的高程。
4．该程序若在fx-3950中的程序清单为：
？→M：？→A：？→B：？→C：？→D：100（A-B）（cos(90-D)）2→X◢ M+Xtan(90-D)-C→Y
说明：M——将测站高程H0+仪器高I；A——上丝读数；B——下丝读数；C——中丝读数；D——竖盘盘左读数L。X——测站点至碎部点的平距；Y——碎部点的高程。
二．FAN SUAN （反算）
1．用途：该程序是“坐标反算公式”程序，用于根据两点1、2的平面坐标（X1，Y1）、（X2，Y2），计算两点间的距离D12及坐标方位角A12。
2． 程序清单：
G“X1”：B“Y1”：C“X2”：H“Y2”：E=C-G：F=H-B ↙
Pol（E，F）：I“D12”◢ J“A12”
3． 程序说明：
X1，Y1——点1的平面坐标；X2，Y2——点2的平面坐标； D12——点1至点2间平距；A12——点1至点2坐标方位角。
由于编程时用到了极坐标函数POL（），故在程序运行中，会出现I=？XXX（数字）及J=？XXX（数字）这是函数POL计算出的两个量，不能改变，直接回车默认即可。
三．ZHENG SUAN （正算）
1．用途：该程序是“坐标正算公式”程序，用于根据点1的平面坐标（X1，Y1），及点1至点2的平距D12、坐标方位角A12，来计算点2的平面坐标（X2，Y2）。
2． 程序清单：
B“X1”：C“Y1”：D“D12”：A“A12” ↙
X“X2”=B+DcosA ◢ Y“Y2”=C+DsinA
3． 程序说明：
X1，Y1——点1的平面坐标；X2，Y2——点2的平面坐标； D12——点1至点2间平距；A12——点1至点2坐标方位角；X2，Y2——点2的平面坐标。另外在输入A12时，可直接输入“度分秒”。
四．YUAN ZHU （圆主）
1．用途：该程序是“单圆曲线主点测设元素及里程计算”程序。
2．程序清单：
A“TURNING ANGLE”：R：B“JD” ↙
T=Rtan(A÷2)◢ L=RAπ÷180◢ E=R÷cos(A÷2)-R◢ D=2T-L◢ C“ZY”=B-T◢ F“YZ”=C+L◢
G“QZ”=F-L÷2
3．程序说明：
TURNING ANGLE——交点JD处的转角；R——圆曲线半径；JD——交点。
T——切线长；L——圆曲线长；E——外矢距；D——切曲差；ZY——ZY点里程；YZ——YZ点里程；QZ——QZ点里程。

确实是不错的计算各式，在工程中比较有用，先谢谢了。

CASIO FX-4800P计算器在导线测量中的应用

一、 概述
导线测量是建立国家平面控制网的方法之一，也可用于工程建
设、城市建设的平面控制测量中。在水电、矿山、道路建设中也经常遇到。随着可编程计算器（FX-4800P）在导线测量中的应用。我们根据导线的计算方法，利用FX-4800P可编程功能适时计算出导线点的坐标。在速度、精度、准确性方面都能满足要求。
二、 附和导线的计算
附和导线就是起始于一个已知控制点，而终止于另一个已知控
制点的导线。
计算公式：
1、 角度闭合差及其分配
fβ=Σβ-(αBM-αNA)-N*180
Vβ=- fβ/N
2、 坐标闭合差及其分配
fx=XB’-XB fy=YB’-YB
Vxi=-(Si/ΣS)*fx Vyi=-(Si/ΣS)*fy
3、 计算待定点坐标
Xi=Xi’+Vxi
Yi=Yi’+Vyi
4、 FX-4800P计算程序
其中N为测站数
fix 0:N:fix 3:Defm 60:Prog“X”:A=W:E“XN=”:F“YN=”:“TN=”：M=0:V=0
LBI 1:V=V+1:Prog“B”:Z[V]=B:Prog“A”:V=N=>Goto2⊿
Prog”D”:Z[N+V]=D:M=M+D:Goto1
LBI 2:T=O-A:fix0:R”△B”=T*3600◢M“∑D”=M◢T=T/N:R=R/N
P”M0”=√(R*R/N) ◢
fix3：K=0:l=0:V=0:A=W:G=X:H=Y:I=0:J=0
LBI 3:Prog”DB”:V≠N-1=>Goto 3⊿P”⊿X”=E-X◢Q” ⊿Y”=F-Y◢
S=√(P*P+Q*Q):K=P/M:L=Q/M:Z”M”=INT(M/S) ◢
X=G:Y=H:A=W:V=0
LBI 4:Prog”DB”POL(X-G,Y-H):J<0=>J=J+360 ⊿
J”FWJ=” ◢I”D=” ◢X”X=” ◢Y”Y=” ◢
G=X:H=Y:V≠N-1=>Goto 4⊿
LBI 5:“END”
X子程序：X“X=”：Y“Y=”：W“TA=”
B子程序：B=0：FIX4：{B}：B：FIX3：Prog“DEG”
A子程序：A=A+B+360:A<0=>A=A+360⊿A>360=>A=A-360
D子程序：D=0：{D}：D“D=”
XY子程序：REC(D,A):X=I+KD+X:Y=J+LD+Y
DB子程序：V=V+1:B=Z[V]+T:Prog“A”:D=Z[V+N]:Prog“XY”
DEG子程序：P=Frac B*100:B=INTB+INTP/60+Frac P/36
三、 支导线的计算
支导线就是从一个已知点出发，既不符合到另一个已知点也不回到原来的点上。支导线没有检核条件，不易发现错误，过不宜采用。
1、计算公式：
Xi+1=Xi+Di*COS(ai)
Yi+1=Yi+Di*SIN(ai)
2、FX-4800P支导线程序
X“X0=”：Y“Y0=”：T“T0=”
LBI 1：E=B：Prog“DEG”:T=T+B+180:T>=360=>T=T-360⊿
X=X+D*COS T◢Y=Y+D*SIN T◢T“TN=” ◢
B=E:Goto 1
以上介绍了导线计算的原理和方法，采用CASIO FX-4800P可编程计算器，使得计算快捷方便、简单，在野外即可完成，有利于提高效率和效益。